***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Mar 31, 2023                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt   PJQ5548-AU   D   G   S
*****param & model definition***
.model  dmos  nmos(
+    l = 1e-6		   w = 1e-6		level = 3
+ kappa = 5e-2
+  vto = 2.16		  kp = 45.6)
.model  dds   d(
+   is = 4.114e-13	   n = 9.812e-1		   rs = 2.647e-3
+   eg = 9.955e-1	trs1 = -8.036e-4)
.model  dbody d(
+   is = 4.114e-13	   n = 9.812e-1		   rs = 2.647e-3
+   eg = 9.955e-1	trs1 = -8.036e-4
+  cjo = 7.047e-10	   m = 1.282e0		   vj = 10
+   bv = 44		 ibv = 250e-6		 tbv1 = 5.646e-4		tt = 25n)
.model  inter  nmos(
+  vto = 0		  kp = 10		level = 1)
.model  dgd    d(
+  cjo = 1.572e-10	   m = 3.752e-1		   vj = 3.950e-1)
.param
+  cgs = 3.236e-11	 cgd = 9.588e-12
+   rd = 1.022e-4	  ra = 1.823e-4		 trd1 = 5.234e-2		tra1 = 5.034e-2
*****function & circuit***
rg	  G  1t   1
cgs	 1t   3   {cgs}   ;ic = 0
egv	  2t  3   table   {v(1t, S)}
+((0   , 0   ),
+ (1   , 1   ),
+ (3   , 3   ),
+ (3.75, 3.78),
+ (4   , 4.02),
+ (4.2 , 4.13),
+ (4.5 , 4.35),
+ (5   , 4.72),
+ (6   , 5   ),
+ (8   , 5.2 ),
+ (10  , 5.25),
+ (20  , 5.3 ),
+ (22  , 5.3 )))
egt	  1  2t   value = {5.121e-4*limit(v(2t,3),0,5)*limit((temp-25),-80,125)}
mmain	  2   1   3   3   dmos
rd	  D   4   {rd}    tc = {trd1}
dds	  3   4   dds
dbody	  3   D   dbody
ra	  4   2   {ra}    tc = {tra1}
rs	  3   5   1e-4
ls	  5   S   0.001n
m1	 1t   8   6   6   inter
e1	  8   6   4   1t  2
cgd	  7   4   {cgd}   ;ic = 0
rcgd	  7   4   10meg
dgd	  6   4   dgd
rdgd	  4   6   10meg
m2	  7   9  1t  1t   inter
e2	  9  1t   4  1t   -2
.ends
*$
